Оптимизирую Scalar SSE

Первый вариант моей оптимизации путем развертывания цикла оказался не очень удачным, как совершенно справедливо указал Иван Колесников в комментариях к посту Scalar SSE. Так что исправляю.

1. Да, организация цикла были весьма корява, исправление существенно увеличило производительность.

2. Ручное переименование регистров, по всей видимости, сбивало с толку механизм, встроенный в процессор. Отказ от него также привел к увеличению производительности.

3. Ручное перемешивание кода, опять же, не давало нормально работать механизму внеочередного исполнения команд. После того, как поставил команды в естественном порядке, код стал работать быстрее.

4. А вот предложение заменить вычитание умножением на -1 и сложением наоборот, замедляло производительность.

5. Не стал реализовать концовку аналогом оператора case (switch). Вот мои соображения:
во-первых, такой оператор не очень быстр: тут либо несколько условных переходов, либо, более быстро косвенный безусловный переход по адресу в памяти (8-ми байтному); не уверен, что адрес будет в кэше, предыдущий длинный цикл по строке скорее всего его вытеснит; и переход такой будет лишь один раз на все итерации внутреннего цикла;
во-вторых, такой вариант не очень хорошо ложится на последующий переход к векторному варианту решения.
Спорно, конечно, но решил что этот вариант не сильно ускорит решение СЛАУ.

Насколько удалось ускорить, покажут будущие тесты.

Вскоре возьмусь за векторный вариант, для начала на SSE.

Ну и напоследок код главного цикла (цикл для верхней строки тоже аналогично оптимизировал; ну и то же самое сделал для FPU):

procedure MakeDoubleNextRowsPASM;
asm
// R8 - P, R9w - n, R10w - index
  lea EBX, [R10d+1]; // BX - i
  cmp BX, R9w;
  jae @exit;
@Loop1:
  mov RCX, [R8 + RBX*8]; // RCX - S
  lea EDX, [R10d+1];
  mov EAX, R9d;  // --
  movsd XMM0, [RCX+R10*8];
  sub EAX, 3;
  cmp EDX, EAX; // --
  jg @Loop2_2;
@Loop2:
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8];
  movsd XMM2, [RCX+RDX*8];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8], XMM2;
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8+8];
  movsd XMM2, [RCX+RDX*8+8];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8+8], XMM2;
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8+16];
  movsd XMM2, [RCX+RDX*8+16];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8+16], XMM2;
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8+24];
  movsd XMM2, [RCX+RDX*8+24];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8+24], XMM2;
  add DX, 4;
  cmp EDX, EAX; // --
  jle @Loop2;
@Loop2_2:
  add EAX, 2;
  cmp EDX, EAX;
  jg @Loop2_1;
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8];
  movsd XMM2, [RCX+RDX*8];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8], XMM2;
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8+8];
  movsd XMM2, [RCX+RDX*8+8];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8+8], XMM2;
  add DX, 2;
@loop2_1:
  cmp DX, R9w; //--
  ja @Loop2_Fin;
  movapd XMM1, XMM0;
  mulsd XMM1, [R11+RDX*8];
  movsd XMM2, [RCX+RDX*8];
  subsd XMM2, XMM1;
  movsd [RCX+RDX*8], XMM2;
@Loop2_Fin:
  inc BX;
  cmp BX, R9w;
  jb @Loop1;
@exit:
end;